home *** CD-ROM | disk | FTP | other *** search
/ User's Choice Windows CD / User's Choice Windows CD (CMS Software)(1993).iso / windows4 / pcproj.zip / PROJ.ACT < prev    next >
Text File  |  1990-01-29  |  7KB  |  258 lines
  1. /* proj.act       --miscelaneous methods, initializations
  2. */
  3.  
  4. /* globals for application colors */
  5. Actor[#CritColor]:=RED;
  6. Actor[#SlackColor]:=BLUE;
  7. !!
  8.  
  9. /* globals for conditional compilation during debugging etc */
  10.  
  11. Actor[#Debug] := false;     /* debugging enable/disable */
  12. Actor[#Trace] := false;     /* trace recalc calls */      
  13. Actor[#CurPos] := 0;        /* text dump of network uses this */ 
  14. !!
  15.  
  16. /* methods for system classes */
  17.  
  18. now(Window)!!
  19.  
  20. /* Set the current cursor position in client coords.
  21.    This is useful when implementing a keyboard interface. */
  22. Def  setCursorPos(self, pos | scrnPos)
  23. { 
  24.   scrnPos := clientToScreen(self, pos);
  25.   Call SetCursorPos(scrnPos.x, scrnPos.y);
  26. }!!
  27.  
  28. /* Return a point of the current cursor position in client coords.
  29.    This is useful when implementing a keyboard interface. */
  30. Def  getCursorPos(self | struct, scrnPos, lpr)
  31. { 
  32.   struct := new(Struct,4);          /* to store the point */
  33.   lpr := lP(struct);                /* long pointer */
  34.   Call GetCursorPos(lpr);           /* device coords */
  35.   scrnPos := pointAt(lpr);          /* get the data */
  36.   freeHandle(struct);               /* free up memory */
  37.   ^screenToClient(self, scrnPos);   /* screen coords */
  38. }!!
  39.  
  40. /* Return a point giving the text width and height
  41.    in the given display context. 
  42.    e.g. for system font the return value might be 
  43.    8@15 for 8 pixels wide, 15 high, depending on the
  44.    Windows drivers. */
  45. Def  textSize(self, hDC | tm1, tm2)
  46. { 
  47.   tm1 := new(Struct, 31);            /* to hold the info */
  48.   Call GetTextMetrics(hDC, lP(tm1)); /* call Windows fn */
  49.   tm2 := getData(tm1);               /* get the data back */
  50.   freeHandle(tm1);                   /* free up memory */
  51.   ^point(low(tm2[10]), low(tm2[0])); /* width@height */
  52. }!!
  53.  
  54. now(Dialog);!!
  55.  
  56. /* Run the dialog with the appropriate resource
  57.    and parent.  Display a warning if it fails. */
  58. Def  checkRunModal(self, res, parent | retValue)
  59. {
  60.   retValue := runModal(self, res, parent);
  61.   if retValue == NOMEM
  62.     beep();
  63.     errorBox(loadString(PW_WARNING),
  64.              loadString(PW_ERRMEM1) + CR_LF +
  65.              loadString(PW_ERRMEM2));
  66.   endif;
  67.   ^retValue;
  68. }!!
  69.  
  70. now(String);!!
  71.  
  72. /* Return the string in a field of fieldSize.
  73.    Truncate or pad with blanks as necessary.
  74. */
  75. Def  field(self, fieldSize | size)
  76. {
  77.   if fieldSize < size := size(self)
  78.     ^subString(self, 0, fieldSize)            /* truncate */
  79.   else
  80.     ^self + stringOf(' ', fieldSize - size);  /* pad */
  81.   endif;
  82. }!!
  83.  
  84. /* Convert to decimal.  Safe if length = 0. */
  85. Def  asDec(self)
  86. {
  87.   if size(self) = 0
  88.     ^ 0;
  89.   else
  90.     ^asInt(self,10);
  91.   endif;
  92. }!!
  93.  
  94. /* Show a yesNoBox with self as the caption, str as message.  
  95.    Return value of 6 = IDYES, 7 = IDNO. */
  96. Def yesNoBox(self, str)
  97. {  ^new(ErrorBox, ThePort, str, self, 4);
  98. }!!
  99.  
  100. /* Convert a string into a Date object.
  101.    Use the international string format.  
  102.    Return nil if not a valid date. */
  103. Def asIntlDate(self | sep, format, ints, posn, pos1, pos2, mm, dd, yy)
  104. { sep := getProfileString(System, "intl", "sDate");
  105.   if sep = "" then sep := "/"; endif;
  106.   format := getProfileString(System, "intl", "iDate");
  107.   select
  108.     case format = "2"
  109.       posn := #(2 0 1); /* YYMMDD */
  110.     endCase
  111.     case format = "1"
  112.       posn := #(1 0 2); /* DDMMYY */
  113.     endCase
  114.     default       
  115.       posn := #(0 1 2); /* MMDDYY */
  116.   endSelect;
  117.   ints := new(Array, 3);
  118.   pos1 := find(self, sep, 0);
  119.   if not(pos1) ^nil; endif;
  120.   ints[0] := asDec(subString(self, 0, pos1));  
  121.   pos2 := find(self, sep, pos1+1);
  122.   if not(pos2) ^nil; endif;
  123.   ints[1] := asDec(subString(self, pos1+1, pos2));
  124.   ints[2] := asDec(subString(self, pos2+1, size(self)));
  125.   mm := ints[posn[0]];  dd := ints[posn[1]];  yy := ints[posn[2]];
  126.   if not(mm) cor mm > 12 cor mm < 1 ^nil; endif;
  127.   if not(dd) cor dd > 31 cor dd < 1 ^nil; endif;
  128.   if not(yy) cor yy < 0 ^nil; endif;
  129.   if yy < 100 yy := yy + 1900; endif;
  130.   ^date(mm, dd, yy);
  131. }!!
  132.  
  133. /* Report an error if the date string is invalid,
  134.    otherwise return the Date object.  Ignore empty strings.
  135.    Report the error according to international date format. */
  136. Def  checkDate(self | retValue, iDate, format)
  137. { 
  138.   if self <> ""
  139.   cand not(retValue := asIntlDate(self))
  140.     beep();
  141.     iDate := getProfileString(System, "intl", "iDate");
  142.     select
  143.       case iDate = "2"
  144.         format := loadString(PW_YYMMDD);
  145.       endCase
  146.       case iDate = "1"
  147.         format := loadString(PW_DDMMYY);
  148.       endCase
  149.       default                               /* "0" or unspecified */
  150.         format := loadString(PW_MMDDYY);
  151.     endSelect;
  152.     errorBox(loadString(PW_ERRDATE1),
  153.              asString(self) + loadString(PW_ERRDATE2) + format +
  154.              loadString(PW_ERRDATE3));
  155.   endif;
  156.   ^retValue;
  157. }!!
  158.  
  159.  
  160. now(Date)!!
  161.  
  162. /* Modify the asString method to use intl format. */
  163. Def asString(self)
  164. {
  165.   ^asIntlString(self);
  166. }!!
  167.  
  168. /* Convert a date to a string.  NilClass:checkString
  169.    returns an empty string. */
  170. Def  checkString(self)
  171. { 
  172.   ^asString(self);
  173. }!!
  174.  
  175.  
  176. /* Return date in international string format. 
  177.    Abbreviate the year.  */
  178. Def asIntlString(self | sep, form, da, yr)
  179. { 
  180.   sep := getProfileString(System, "intl", "sDate");
  181.   if sep = "" sep := "/"; endif;
  182.   form := getProfileString(System, "intl", "iDate");
  183.   da := asDateArray(self); 
  184.   if da[2] > 1900
  185.     yr := subString(asString(da[2]), 2, 4);
  186.   else
  187.     yr := asString(da[2]);
  188.   endif;
  189.   select
  190.     case form = "2" /* YYMMDD */
  191.      ^yr+sep+asString(da[1])+sep+asString(da[0]);
  192.     endCase
  193.     case form = "1" /* DDMMYY */
  194.      ^asString(da[1])+sep+asString(da[0])+sep+yr;
  195.     endCase
  196.     default         /* MMDDYY */
  197.      ^asString(da[0])+sep+asString(da[1])+sep+yr;
  198.     endSelect;
  199. }!!
  200.  
  201.  
  202. now(Int)!!
  203.  
  204. /* Create a date object with a starting value. */
  205. Def date(self, dd, yy)
  206. {
  207.   ^date(new(Date), self, dd, yy);
  208. }!!
  209.  
  210.  
  211. now(NilObject)!!
  212.  
  213. /* Return an empty string.  For compatibility
  214.    with the Date class so you can checkString(nil)
  215.    or checkString(aDate) and get a string. */
  216. Def  checkString(self)
  217. { 
  218.   ^"";
  219. }!!
  220.  
  221.  
  222. now(Collection)!!
  223.  
  224. /* Returns true (the position) if the elem is in the collection.
  225.    Uses a sequential search.  Descendent classes redefine this
  226.    using more efficient means where possible. */
  227. Def  in(self, elem)
  228. {
  229.   do(size(self),
  230.     {using(i) 
  231.      if self[i] = elem ^i; endif;   /* found */
  232.   });
  233.   ^false;    /* not found */
  234. }!!
  235.  
  236.  
  237. now(Dictionary)!!
  238.  
  239. /* Returns the value (true) if the key is in the Dictionary. */
  240. Def  in(self, key | assoc)
  241. {
  242.   assoc := assocAt(self, key);
  243.   if assoc
  244.     ^assoc.value;
  245.   else
  246.     ^false;
  247.   endif;
  248. }!!
  249.  
  250. now(Object)!!
  251. /* This method overrides the default case of objects not being
  252.    storable so that Project, Milestone, Task etc are all storable.
  253. */
  254. Def notStorable(self)
  255. {
  256.   ^nil;
  257. }!!
  258.